'---------------------------------------------------------------------------------------------------
' 용    도 : 시장 코멘트 달력 초기화
' 파라미터 : strDate - 날짜
' 리    턴 : 없음
'---------------------------------------------------------------------------------------------------
Sub fnSetCalendar(strDate)
  Dim strBuff      '임시 문자열 변수
  Dim strLastDay   '파라미터로 넘어온 월의 마지막 일
  Dim nDifference  '일요일과 파라미터로 넘어온 월의 1일에 해당되는 요일과의 차이
  Dim i            'Loop 변수
  
  '// 파라미터로 넘어온 날짜를 "YYYY/MM/01" 형식으로 만든다
  strDate = Left(strDate, 4) & "/" & Mid(strDate, 5, 2) & "/01"
  
  '// 파라미터로 넘어온 월의 마지막 일자를 얻는다
  strBuff = Left(DateAdd("m", 1, strDate), 7) & "/01"  '다음달의 첫날을 구한다
  strBuff = DateAdd("d", -1, strBuff)  '하루전 날짜를 구한다
  strLastDay = Right(strBuff, 2)  '구한 날짜는 파라미터로 넘어온 월의 마지막 날짜인데
                                  '월의 일수를 얻기위해 일 두자리 만을 얻는다
  
  '// 일요일과 파라미터로 넘어온 월의 1일에 해당되는 요일과의 차이를 구한다
  nDifference = Weekday(strDate) - 1
  
  '// ***** 파라미터로 넘어온 년도와 월에 해당되는 달력을 만든다 **************************************
  '// 달력에 해당 년도와 월을 표시한다
  tdDate.innerText = " " & Left(strDate, 4) & "년 " & Mid(strDate, 6, 2) & "월"
  
  '// 일자를 출력한다
  For i = 1 To CInt(strLastDay)
    tdDay(nDifference + i - 1).innerText = CStr(i)
    
    If (nDifference + i - 1) Mod 7 <> 0 And (nDifference + i - 1) Mod 7 <> 6 Then
      tdDay(nDifference + i - 1).style.cursor = "hand"
    End If
  Next
End Sub

'---------------------------------------------------------------------------------------------------
' 용    도 : 현재월에서 월 증가치 만큼 더해진 달의 첫 날짜를 구한다
' 파라미터 : strDate - 날짜, nDifference - 월 증가치
' 리    턴 : 없음
'---------------------------------------------------------------------------------------------------
Function fnGetAddedDate(strDate, nDifference)
  '// 파라미터로 넘어온 날짜를 "YYYY/MM/01" 형식으로 만든다
  strDate = Left(strDate, 4) & "/" & Mid(strDate, 5, 2) & "/01"
  
  '// 월 증가치에 해당되는 날짜(YYYYMM01)를 만든다
  strDate = Left(DateAdd("m", nDifference, strDate), 7) & "01"
  strDate = Left(strDate, 4) & Mid(strDate, 6, 2) & "01"
  
  fnGetAddedDate = strDate
End Function

'---------------------------------------------------------------------------------------------------
' 용    도 : 현재월에서 월 증가치 만큼 더해진 날짜를 구한다
' 파라미터 : strDate - 날짜, nDifference - 월 증가치
' 리    턴 : 없음
'---------------------------------------------------------------------------------------------------
Function fnAddMonth(strDate, nDifference)
  '// 파라미터로 넘어온 날짜를 "YYYY/MM/DD" 형식으로 만든다
  strDate = Left(strDate, 4) & "/" & Mid(strDate, 5, 2) & "/" & Right(strDate, 2)
  
  '// 월 증가치에 해당되는 날짜(YYYYMMDD)를 만든다
  strDate = DateAdd("m", nDifference, strDate)
  strDate = DateAdd("d", 1, strDate)
  strDate = Left(strDate, 4) & Mid(strDate, 6, 2) & Right(strDate, 2)
  
  fnAddMonth = strDate
End Function